.TITLE	GAD
	.IDENT	/AG07.3/

R$$T11	=	0			;UNCOMENT FOR RT, COMMENT FOR RSX

CR	=	15			;CARRIAGE RETURN
LF	=	12			;LINE FEED
ESC	=	33			;ESCAPE
CTRLC	=	3			;CTRL/C
CTRLZ	=	32			;CTRL/Z
CTRLW	=	27			;CTRL/W

.IF	NDF	R$$T11
	.MCALL	ASTX$S,DIR$,EXIT$S,MRKT$,QIOW$
	.MCALL	WTSE$

QKIL:	QIOW$	IO.KIL,5,1
QIOW:	QIOW$	IO.WAL,5,1,,,,<BUFF>
QWAL:	QIOW$	IO.WAL,5,1,,,,<POSBF>
QATA:	QIOW$	IO.ATA,5,1,,,,<KBAST>
MRKT:	MRKT$	7,5,1
WTSE:	WTSE$	7
.IFF	;NDF	R$$T11
$JSW	=	44			;JOB STATUS WORK
TTSPC$	=	10000			;SPECIAL TTY MODE BIT
TCBIT$	=	100			;INHIBIT TTY WAIT BIT

$SYSVE	=	276			;MONITOR VERSION NUMBER BYTE
$CNFG1	=	300			;SYSTEM CONFIGURATION WORD
FBMON$	=	1			;FB/XM MONITOR BIT (FOR < 5.6)
$SYSUP	=	277			;MONITOR VERSION RELEASE LEVEL BYTE
$SYSGE	=	372			;SYSTEM GENERATION FEATURES WORD
TSXP$	=	100000			;RUNNING UNDER TSX-PLUS BIT
TIMER$	=	2000			;[SJ] TIMER SUPPORT BIT

	.ASECT
	.=$JSW
	.WORD	TTSPC$!TCBIT$
	.PSECT

	.MCALL	.EXIT,.GVAL,.MRKT,.PRINT
	.MCALL	.RSUM,.SPND,.SCCA,.TTINR

AREA:	.BLKW	4
SCCA:	.WORD	0
MRKT:	.WORD	0,5
M.KTMG	=	2

CRTN:	.RSUM
	RETURN
.ENDC	;NDF	R$$T11

POSBF:	.BLKB	10.
BUFF:	.BLKB	86.
KBBUFF:	.BLKB	26.
L1076:	.WORD	23420,1750,144,12,0
L1110:	.WORD	040503,041104
TIMOUT:	.BLKW
OFFSET:	.BLKW

COL:	.BLKW
ROW:	.BLKW

L1124:	.BLKW
L1126:	.BLKW
L1130:	.BLKW

LEFTCH:	.BLKW				;1132
RIGHCH:	.BLKW				;1134
DIRECT:	.BLKW				;1136

KBHEAD:	.BLKW				;1140
KBTAIL:	.BLKW				;1142
DRAWFL:	.BLKW				;1144
KBCHAR:	.BLKW				;1146
L1150:	.BLKW
L1152:	.BLKW
SCORE:	.BLKW				;1154
	.BLKW	3			;1156

L1164:	.BLKW
L1166:	.BLKW

INIT:	MOV	#BUFF,R5
	MOV	#KBHEAD,R1
	MOV	#8.,R2				;XXX
	MOV	#KBBUFF,(R1)+
	MOV	#KBBUFF,(R1)+
10$:	CLR	(R1)+
	SOB	R2,10$
	CALL	RAND
	MOV	R0,(R1)+
	CALL	RAND
	MOV	R0,(R1)+
	RETURN

START:
.IF	NDF	R$$T11
	MOV	R1,COL			;TASK NAME 1ST PART
	DIR$	#QATA
.IFF	;DF	R$$T11
	.GVAL	#AREA,#$SYSGE		;GET SYSGEN WORD
	MOV	R0,R5			;SAVE IT
	.GVAL	#AREA,#$SYSVE		;GET SYSTEM VERSION
	CMPB	#5,R0			;CHECK FOR V5
	BGT	5$			;<5.0, CHECK FBMON$
	BNE	6$			;>5, DON'T CHECK FBMON
	SWAB	R0			;GET SYSUPD
	CMPB	#5,R0			;CHECK FOR 5.5
	BLT	6$			;>5.5, DON'T CHECK FBMON$
5$:	.GVAL	#AREA,#$CNFG1		;GET CONFIG WORD
	BIT	#FBMON$,R0		;RUNNING UNDER FB/XM?
	BNE	7$			;YES, TIMER SUPPORTED
6$:	BIT	#TIMER$,R5		;TIMER SUPPORTED?
	BNE	7$			;YES
	.PRINT	#NOTIM			;NO, ERROR
	.EXIT				;EXIT
7$:	TST	R5			;RUNNING UNDER TSX-PLUS?
	BPL	8$			;PL -> NO
	.GVAL	#AREA,#-4		;GET TSX-PLUS LEAD-IN CHAR
	MOVB	R0,TSXS			;SET UP NOWAIT/SINGLECHAR
	MOVB	R0,TSXS+2		;...MODE
	.PRINT	#TSXS			;...
8$:	.SCCA	#AREA,#SCCA
.ENDC	;NDF	R$$T11
	CALL	INIT
.IF	NDF	R$$T11
	CMP	#^RTT0,COL
	BNE	10$
	CALL	REDRAW
.ENDC	;NDF	R$$T11
10$:	CALL	CLSCR
	MOV	#1,MRKT+M.KTMG
	MOV	#4,R0
	MOV	#ASKL,R0
20$:	MOVB	(R0)+,(R5)+
	BNE	20$
	DEC	R5
	CALL	PRINT
30$:	CALL	GETCHT
	TST	R0
	BMI	40$
	DEC	R0
	INC	MRKT+M.KTMG
40$:	MOV	KBCHAR,LEFTCH
	BEQ	30$
50$:	MOV	#ASKR,R0
60$:	MOVB	(R0)+,(R5)+
	BNE	60$
	DEC	R5
	CALL	PRINT
70$:	CALL	GETCHT
	MOV	KBCHAR,RIGHCH
	BEQ	70$
	CMP	LEFTCH,RIGHCH
	BEQ	50$
	MOV	#2,DIRECT

RESTRT:	MOV	#SCBUF+80.,R0			;WORKPLACE
	MOV	#22.,R2				;22.
10$:	MOV	#78.,R1				;78.
	INC	R0				;SKIP BORDER
20$:	MOVB	#<' >,(R0)+			;CLEAR CELL
	SOB	R1,20$				;LOOP
	INC	R0				;SKIP BORDER
	SOB	R2,10$				;LOOP
	CALL	REDRAW
	MOV	#20,R1
	CALL	GETRND
	ADD	#3,R0
	MOV	R0,R2
	MOV	#104,R1
	CALL	GETRND
	ADD	#5,R0
	MOV	R0,R1
	CALL	GETOFS
	MOV	R0,OFFSET
	ADD	#40,R1
	ADD	#40,R2
	MOV	R1,COL
	MOV	R2,ROW
	MOVB	#'$,(R0)+
	MOVB	#'D,(R0)+
	MOVB	#'D,@R0
	ADD	#2,R1
	MOV	R0,L1124
	MOV	R1,L1126
	MOV	R2,L1130
	MOV	#7,TIMOUT
	MOV	#7,MRKT+M.KTMG
.IF	NDF	R$$T11
	DIR$	#MRKT
.IFF	;NDF	R$$T11
	MOV	R0,-(SP)
	.MRKT	#AREA,#MRKT,#CRTN,#7
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11

LOOP:
.IF	NDF	R$$T11
	DIR$	#WTSE
.IFF	;NDF	R$$T11
	.SPND
.ENDC	;NDF	R$$T11
	MOV	#DIRECT,R1
	MOV	@R1,R2
	CALL	GETCH
	MOV	KBCHAR,R0
	BEQ	30$
	ADD	SEED,SEED+2
	CMP	R0,LEFTCH
	BNE	10$
	INC	R2
	BR	20$
10$:	CMP	R0,RIGHCH
	BNE	30$
	DEC	R2
20$:	BIC	#^C3,R2
	MOV	R2,@R1
	MOV	#11,TIMOUT
	BIT	#1,R2
	BNE	30$
	MOV	#7,TIMOUT
30$:	MOV	#POSBF,R4
	MOV	#<ESC>+<'Y*400>,(R4)+
	MOVB	ROW,(R4)+
	MOVB	COL,(R4)+
	MOV	OFFSET,R0
	MOVB	L1110(R2),@R0
	ASL	R2
	JMP	@DIRTAB(R2)

DIRR:	INC	R0
	INC	COL
	BR	DIRDON

DIRU:	SUB	#80.,R0
	DEC	ROW
	BR	DIRDON

DIRL:	DEC	R0
	DEC	COL
	BR	DIRDON

DIRD:	ADD	#80.,R0
	INC	ROW
	BR	DIRDON

DIRTAB:	.WORD	DIRR,DIRU,DIRL,DIRD

DIRDON:	MOV	TIMOUT,MRKT+M.KTMG
.IF	NDF	R$$T11
	DIR$	#MRKT
.IFF	;NDF	R$$T11
	MOV	R0,-(SP)
	.MRKT	#AREA,#MRKT,#CRTN,#7
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11
	MOVB	@R0,R2
	CMPB	#40,R2		;SPACE
	BEQ	30$
	CMPB	#61,R2		;1
	BGT	20$
	CMPB	#71,R2		;9
	BCS	20$
	SUB	R2,L1166
	SUB	R2,L1166
	ADD	R2,L1164
	BVC	10$
	CLR	L1164
10$:	SUB	#60,R2
	ASL	R2
	ADD	R2,L1150
	BR	30$
20$:	MOV	#BUFF,R5
.IF	NDF	R$$T11
	DIR$	#WTSE
.IFF	;NDF	R$$T11
	MOV	R0,-(SP)
	.SPND
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11
	JMP	FINISH
30$:	MOV	#15443,(R4)+
	MOV	#15504,(R4)+
	MOV	@R1,R2
	MOVB	L1110(R2),(R4)+
	MOVB	#'$,@R0
	MOVB	@R0,@R4
	MOV	R0,OFFSET
.IF	NDF	R$$T11
	MOV	R5,QWAL+Q.IOPL+2
	SUB	#POSBF,QWAL+Q.IOPL+2
	MOV	#BUFF,R5
	DIR$	#QWAL
.IFF	;NDF	R$$T11
	MOVB	#200,@R5
	MOV	#BUFF,R5
	MOV	R0,-(SP)
	.PRINT	#POSBF
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11

	MOV	#L1150,R1
	MOV	#L1152,R0
	INC	@R0
	BIT	#1,@R0
	BEQ	50$
	INC	SCORE
	CMP	#24,@R0
	BGT	40$
	INC	@R1
	CLR	@R0
	SUB	#10.,SCORE
40$:	TST	@R1
	BEQ	50$
	ADD	#10.,SCORE
	DEC	@R1
	BR	MOVEIT
50$:	MOV	L1124,R0
	MOVB	@R0,R1
	MOVB	#<' >,@R0
	MOVB	#ESC,(R5)+
	MOVB	#'Y,(R5)+
	MOVB	L1130,(R5)+
	MOVB	L1126,(R5)+
	MOVB	#<' >,(R5)+
	SUB	#'A,R1
	ASL	R1
	JMP	@MOVTAB(R1)

MOVU:	DEC	L1130
	SUB	#80.,R0
	BR	MOVDON

MOVD:	INC	L1130
	ADD	#80.,R0
	BR	MOVDON

MOVR:	INC	L1126
	INC	R0
	BR	MOVDON

MOVL:	DEC	L1126
	DEC	R0
	BR	MOVDON

MOVTAB:	.WORD	MOVU,MOVD,MOVR,MOVL

MOVDON:	MOV	R0,L1124
MOVEIT:	MOV	#L1164,R2
	MOV	#L1166,R3
	SUB	#4,@R3
	BPL	10$
	CALL	RAND
	MOV	R0,@R3
	MOV	#9.,R1
	CALL	GETRND
	ADD	#'1,R0
	MOV	R0,R4
	BR	20$
10$:	SUB	#3,@R2
	BPL	50$
	CALL	RAND
	MOV	R0,@R2
	MOV	#77.,R4
20$:	MOV	#22.,R1
	CALL	GETRND
	MOV	R0,R2
	INC	R2
	MOV	#78.,R1
	CALL	GETRND
	MOV	R0,R1
	INC	R1
	CALL	GETOFS
	CMPB	#<' >,@R0
	BEQ	30$
	CMPB	#'M,R4
	BNE	50$
	MOV	#-1,@R3
	BR	50$
30$:	ADD	#40,R1
	ADD	#40,R2
	CMPB	#'M,R4
	BNE	40$
	CMP	R1,COL
	BEQ	50$
	CMP	R2,ROW
	BEQ	50$
40$:	MOVB	R4,@R0
	MOVB	#ESC,(R5)+
	MOVB	#'Y,(R5)+
	MOVB	R2,(R5)+
	MOVB	R1,(R5)+
	MOVB	R4,(R5)+
50$:	BIT	#1,L1152
	BNE	60$
	CALL	PSCOR
60$:	JMP	LOOP

FINISH:	TST	DIRECT
	BNE	10$
	INC	DIRECT
10$:	TST	L1150
	BEQ	30$
20$:	ADD	#8.,SCORE
	DEC	L1150
	BNE	20$
30$:	CALL	PSCOR
	MOVB	#ESC,(R5)+
	MOVB	#'Y,(R5)+
	MOVB	#40,(R5)+
	MOVB	#52,(R5)+
	CALL	PRINT
	MOV	SCORE,R4
	SWAB	R4
	BIC	#177401,R4
	CMP	#100,R4
	BGT	50$
	MOV	#NHARES,R0
40$:	MOVB	(R0)+,(R5)+
	BNE	40$
	DEC	R5
	BR	80$
50$:	MOVB	#<' >,(R5)+
	CALL	RAND
	CMP	#58.,R0
	BGT	60$
	MOVB	#'w,(R5)+
	MOVB	#'y,(R5)+
	MOVB	#<' >,(R5)+
	MOV	MTAB1(R4),R0
	BR	70$
60$:	MOV	MTAB2(R4),R0
70$:	CALL	PSTRS
80$:	CALL	PRINT
	MOV	#30.,MRKT+M.KTMG
.IF	NDF	R$$T11
	DIR$	#MRKT
	DIR$	#WTSE
.IFF	;NDF	R$$T11
	MOV	R0,-(SP)
	.MRKT	#AREA,#MRKT,#CRTN,#7
	.SPND
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11
90$:	CALL	GETCH
	TST	KBCHAR
	BNE	90$
	MOVB	#7,(R5)+
	CALL	PRINT
	MOV	#100.,MRKT+M.KTMG
.IF	NDF	R$$T11
	DIR$	#MRKT
	DIR$	#WTSE
.IFF	;NDF	R$$T11
	MOV	R0,-(SP)
	.MRKT	#AREA,#MRKT,#CRTN,#7
	.SPND
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11
100$:	MOV	#10.,MRKT+M.KTMG
	MOV	#40.,SCORE
	CALL	GETCH
	TST	KBCHAR
	BNE	120$
.IF	NDF	R$$T11
	DIR$	#MRKT
	DIR$	#WTSE
.IFF	;NDF	R$$T11
	MOV	R0,-(SP)
	.MRKT	#AREA,#MRKT,#CRTN,#7
	.SPND
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11
	DEC	SCORE
	BNE	100$
	BR	130$
110$:	CALL	GETCH
	TST	KBCHAR
	BNE	110$
120$:	CALL	INIT
	JMP	RESTRT
130$:	CALL	CLSCR
	MOV	#<ESC>+<'Y*400>,(R5)+
	MOV	#20066,(R5)+
	CALL	PRINT
.IF	NDF	R$$T11
	EXIT$S
.IFF	;NDF	R$$T11
	.EXIT
.ENDC	;NDF	R$$T11

.IF	NDF	R$$T11
KBAST:	BIC	#^C177,@SP
	MOVB	(SP)+,@KBHEAD
	CMP	KBHEAD,#KBBUFF+26.
	BEQ	10$
	CMPB	#CTRLZ,@KBHEAD
	BNE	20$
10$:	DIR$	#QKIL
	MOV	#BUFF,R5
	MOV	#<ESC>+<'Y*400>,(R5)+
	MOV	#20066,(R5)+
	CALL	PRINT
	EXIT$S
20$:	CMPB	#CTRLW,@KBHEAD
	BNE	30$
	TSTB	DRAWFL
	BNE	40$
	DIR$	#QKIL
	CALL	REDRAW
	BR	40$
30$:	CMPB	#ESC,@KBHEAD
	BEQ	40$
	INC	KBHEAD
40$:	ASTX$S
.ENDC	;NDF	R$$T11

PSCOR:	MOVB	#ESC,(R5)+
	MOVB	#'Y,(R5)+
	MOVB	#40,(R5)+
	MOVB	#45,(R5)+
	MOV	SCORE,R0
	MOV	#L1076,R1
10$:	MOV	#'0,R3
	MOV	(R1)+,R2
	BEQ	30$
20$:	INC	R3
	SUB	R2,R0
	BPL	20$
	DEC	R3
	MOVB	R3,(R5)+
	ADD	R2,R0
	BR	10$
30$:	ADD	R0,R3
	MOVB	R3,(R5)+
	RETURN

GETCH:
.IF	NDF	R$$T11
	CMP	KBHEAD,KBTAIL
	BNE	10$
	MOV	#KBBUFF,KBHEAD
	MOV	#KBBUFF,KBTAIL
	CLR	KBCHAR
	RETURN
10$:	MOVB	@KBTAIL,KBCHAR
	INC	KBTAIL
	RETURN
.IFF	;NDF	R$$T11
	CLR	KBCHAR
	MOV	R0,-(SP)
	.TTINR
	BCS	10$
	CMPB	#CTRLC,R0
	BEQ	20$
	CMPB	#CTRLZ,R0
	BEQ	20$
	MOV	R0,KBCHAR
10$:	MOV	(SP)+,R0
	RETURN
20$:	MOV	#BUFF,R5
	CALL	CLSCR
	CALL	PRINT
	.EXIT
.ENDC	;NDF	R$$T11

GETCHT:	CALL	GETCH
.IF	NDF	R$$T11
	DIR$	#MRKT
	DIR$	#WTSE
.IFF	;NDF	R$$T11
	MOV	R0,-(SP)
	.MRKT	#AREA,#MRKT,#CRTN,#7
	.SPND
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11
	ADD	SEED,SEED+2
	RETURN

GETOFS:	MOV	R1,-(SP)
	MOV	R2,-(SP)
	MOV	#80.,R1
	MOV	#SCBUF,R0
	BR	30$
10$:	ADD	R1,R0
20$:	ASL	R1
30$:	ROR	R2
	BCS	10$
	BNE	20$
	MOV	(SP)+,R2
	MOV	(SP)+,R1
	ADD	R1,R0
	RETURN

REDRAW:	MOVB	SP,DRAWFL
	MOV	R0,-(SP)
	MOV	R1,-(SP)
	MOV	R2,-(SP)
	MOV	R3,-(SP)
.IF	NDF	R$$T11
	DIR$	#QKIL
.ENDC	;NDF	R$$T11
	MOV	#BUFF,R5
	CALL	CLSCR
	MOV	#23.,R2
	MOV	#SCBUF,R0
	MOV	#20040,R3			;POSITION
10$:	MOV	#80.,R1
20$:	MOVB	(R0)+,@R5
	CMPB	#'C,@R5
	BEQ	30$
	CMPB	#'D,@R5
	BEQ	30$
	CMPB	#'A,@R5
	BEQ	30$
	CMPB	#'B,@R5
	BNE	40$
30$:	MOVB	#'#,@R5
40$:	INC	R5
	SOB	R1,20$
	INC	R3
	MOV	#<ESC>+<'Y*400>,(R5)+
	MOV	R3,(R5)+
	CALL	PRINT
	SOB	R2,10$
	MOV	#79.,R1
50$:	MOVB	(R0)+,(R5)+
	SOB	R1,50$
	CALL	PRINT
	MOV	(SP)+,R3
	MOV	(SP)+,R2
	MOV	(SP)+,R1
	MOV	(SP)+,R0
	CLRB	DRAWFL
	RETURN

PRINT:
.IF	NDF	R$$T11
	MOV	R5,QIOW+Q.IOPL+2
	SUB	#BUFF,QIOW+Q.IOPL+2
	BLE	10$
	DIR$	#QIOW
.IFF	;NDF	R$$T11
	MOVB	#200,@R5
	SUB	#BUFF,R5
	BLE	10$
	MOV	R0,-(SP)
	.PRINT	#BUFF
	MOV	(SP)+,R0
.ENDC	;NDF	R$$T11
10$:	MOV	#BUFF,R5
	RETURN

CLSCR:	MOV	#<ESC>+<'H*400>,(R5)+
	MOV	#<ESC>+<'J*400>,(R5)+
	RETURN

PSTRS:	MOV	(R0)+,R1
	BNE	10$
	RETURN
10$:	MOVB	(R1)+,(R5)+
	BNE	10$
	DEC	R5
	CALL	PRINT
	BR	PSTRS

GETRND:	CALL	RAND
	ASL	R1
10$:	SUB	R1,R0
	BPL	10$
	ASR	R1
	ADD	R1,R0
	BPL	20$
	ADD	R1,R0
20$:	RETURN

RAND:	MOV	#SEED,R0
	INCB	@R0
	BVC	10$
	INC	2(R0)
10$:	ADD	(R0)+,@R0
	MOV	@R0,R0
	BIC	#^C377,R0
	MOVB	SEED+4(R0),R0
	BIC	#^C377,R0
	RETURN

SEED:	.WORD	111,7
	.BYTE	012,207,315,020,050,136,310,145
	.BYTE	122,137,124,244,334,147,250,116
	.BYTE	353,302,105,312,120,306,317,344
	.BYTE	021,143,270,322,162,106,243,133
	.BYTE	047,132,275,104,360,073,366,251
	.BYTE	001,130,170,267,023,377,113,316
	.BYTE	054,313,066,035,236,303,033,230
	.BYTE	266,352,025,107,347,354,146,350
	.BYTE	263,006,330,331,200,134,226,063
	.BYTE	363,252,367,076,342,037,171,365
	.BYTE	135,254,305,214,117,201,067,016
	.BYTE	142,065,161,234,064,062,055,045
	.BYTE	111,152,346,335,075,255,336,237
	.BYTE	224,340,014,056,160,003,036,225
	.BYTE	163,233,032,213,015,154,375,221
	.BYTE	176,264,174,031,125,320,205,355
	.BYTE	246,216,172,202,042,311,341,044
	.BYTE	103,112,141,215,127,022,102,071
	.BYTE	372,332,153,351,274,261,301,110
	.BYTE	276,362,323,232,034,157,167,077
	.BYTE	376,114,333,370,314,374,271,057
	.BYTE	337,321,017,371,121,043,220,074
	.BYTE	247,262,304,324,026,242,156,041
	.BYTE	027,206,150,040,013,002,307,227
	.BYTE	212,173,165,155,046,024,222,343
	.BYTE	166,072,060,164,204,373,265,240
	.BYTE	123,004,223,357,115,277,100,203
	.BYTE	325,070,051,101,053,177,011,010
	.BYTE	235,272,000,007,257,151,231,256
	.BYTE	217,245,361,211,131,175,253,364
	.BYTE	030,345,210,260,140,273,326,356
	.BYTE	052,241,126,327,005,061,300,144

MTAB1:	.WORD	MV1,MV2,MV2.1,MV3.1,MV3,MV4,MV4.1,MV4.2,MV5.1,MV5
	.WORD	MV6,MV7,MV7.1,MV8.1,MV8,MV9,MV10,MV11,MV11.1,MV11.2
	.WORD	MV12.1,MV12,MV13,MV14,MV14.1,MV15,MV16,MV16.1,MV16.2
	.WORD	MV17.1,MV17,MV18

MTAB2:	.WORD	MV19,MV20,MV20.1,MV20.2,MV21,MV22,MV23,MV24,MV25.1
	.WORD	MV26,MV25,MV27,MV28,MV27.2,MV28.1,MV23.1,MV30,MV29
	.WORD	MV27.1,MV31,MV30.2,MV32.2,MV30.1,MV33,MV32.1,MV34.1
	.WORD	MV32,MV34,MV33.1,MV35,MV36.1,MV36

MV1:	.WORD	MSG0,0
MV2:	.WORD	MSG2
MV2.1:	.WORD	MSG4,MSG21,0
MV3:	.WORD	MSG2
MV3.1:	.WORD	MSG5,MSG21,0
MV4:	.WORD	MSG2
MV4.1:	.WORD	MSG4
MV4.2:	.WORD	MSG33,0
MV5:	.WORD	MSG2
MV5.1:	.WORD	MSG5,MSG33,0
MV6:	.WORD	MSG23,MSG33,0
MV7:	.WORD	MSG4
MV7.1:	.WORD	MSG27,0
MV8:	.WORD	MSG2
MV8.1:	.WORD	MSG5,MSG27,0
MV9:	.WORD	MSG23,MSG27,0
MV10:	.WORD	MSG23,MSG17,MSG27,0
MV11:	.WORD	MSG2
MV11.1:	.WORD	MSG4
MV11.2:	.WORD	MSG31,0
MV12:	.WORD	MSG2
MV12.1:	.WORD	MSG5,MSG31,0
MV13:	.WORD	MSG23,MSG31,0
MV14:	.WORD	MSG23,MSG17,MSG31,0
MV14.1:	.WORD	MSG23,MSG17,MSG31,MSG13,MSG15,0
MV15:	.WORD	MSG23,MSG17,MSG31,MSG13,MSG15,MSG28,MSG29,0
MV16:	.WORD	MSG2
MV16.1:	.WORD	MSG4
MV16.2:	.WORD	MSG9,0
MV17:	.WORD	MSG17
MV17.1:	.WORD	MSG25,MSG9,0
MV18:	.WORD	MSG7,MSG28,MSG17,MSG25,MSG9,MSG13,MSG19,0
MV19:	.WORD	MSG8,MSG1,0
MV20:	.WORD	MSG2,MSG0.1,MSG28
MV20.1:	.WORD	MSG2
MV20.2:	.WORD	MSG3,0
MV21:	.WORD	MSG0.1,MSG28,MSG3,0
MV22:	.WORD	MSG4,MSG22,0
MV23:	.WORD	MSG20,MSG16,MSG28
MV23.1:	.WORD	MSG8,MSG24,0
MV24:	.WORD	MSG6,MSG8,MSG24,0
MV25:	.WORD	MSG8,MSG14
MV25.1:	.WORD	MSG8,MSG11,0
MV26:	.WORD	MSG8,MSG11,MSG28,MSG20,MSG16,0
MV27:	.WORD	MSG8,MSG24,MSG28
MV27.1:	.WORD	MSG20
MV27.2:	.WORD	MSG16,0
MV28:	.WORD	MSG2
MV28.1:	.WORD	MSG18,MSG22,0
MV29:	.WORD	MSG26,MSG22,0
MV30:	.WORD	MSG8
MV30.1:	.WORD	MSG2
MV30.2:	.WORD	MSG30,MSG22,0
MV31:	.WORD	MSG8,MSG14,MSG8,MSG24,0
MV32:	.WORD	MSG20
MV32.1:	.WORD	MSG16,MSG28
MV32.2:	.WORD	MSG32,0
MV33:	.WORD	MSG8,MSG11,MSG28
MV33.1:	.WORD	MSG6,MSG32,0
MV34:	.WORD	MSG2
MV34.1:	.WORD	MSG5,MSG22,0
MV35:	.WORD	MSG34,MSG22,0
MV36:	.WORD	MSG2
MV36.1:	.WORD	MSG35,MSG10,0

;005526
NHARES:	.ASCIZ	/ zajcy kon~ilisx /
MSG0:	.ASCIZ	<ESC>/Y/<40><53>
MSG0.1:	.ASCIZ	/malo /
MSG1:	.ASCIZ	/spi /
MSG2:	.ASCIZ	/o~enx /
MSG3:	.ASCIZ	/ploho /
MSG4:	.ASCIZ	/malenxkij /
MSG5:	.ASCIZ	/bolx{oj /
MSG6:	.ASCIZ	/lu~{e /
MSG7:	.ASCIZ	/gromadnyj /
MSG8:	.ASCIZ	/ne /
MSG9:	.ASCIZ	/zmej goryny~ /
MSG10:	.ASCIZ	/pobeda /
MSG11:	.ASCIZ	/suetisx /
MSG12:	.ASCIZ	/pobeda /
MSG13:	.ASCIZ	/poviratelx /
MSG14:	.ASCIZ	/nado, /
MSG15:	.ASCIZ	/bykow /
MSG16:	.ASCIZ	/wnimatelxnee /
MSG17:	.ASCIZ	/uvasnyj /
MSG18:	.ASCIZ	/posredstwennyj /
MSG19:	.ASCIZ	/krolikow /
MSG20:	.ASCIZ	/budx /
MSG21:	.ASCIZ	/uv /
MSG22:	.ASCIZ	/rezulxtat /
MSG23:	.ASCIZ	/kolossalxnyj /
MSG24:	.ASCIZ	/toropisx /
MSG25:	.ASCIZ	/ognedy{a}ij /
MSG26:	.ASCIZ	/srednij /
MSG27:	.ASCIZ	/piton /
MSG28:	.ASCIZ	/i /
MSG29:	.ASCIZ	/swinej /
MSG30:	.ASCIZ	/horo{ij /
MSG31:	.ASCIZ	/udaw /
MSG32:	.ASCIZ	/|konomx mesto /
MSG33:	.ASCIZ	/poloz /
MSG34:	.ASCIZ	/otli~nyj /
MSG35:	.ASCIZ	/skoro/

SCBUF:	.ASCII	/s~et:00000++++++++++++++++++++++++++++++++++++++++++++++++++/
	.ASCII	/++++++++++++++++++++/
	.ASCII	/+                                                           /
	.ASCII	/                   +/
	.ASCII	/+                                                           /
	.ASCII	/                   +/
	.ASCII	/+                                                           /
	.ASCII	/                   +/
	.ASCII	/+                                                           /
	.ASCII	/                   +/
	.ASCII	/+                         :::     :::::     :::             /
	.ASCII	/                   +/
	.ASCII	/+                       :::::     :::::     :::::           /
	.ASCII	/                   +/
	.ASCII	/+                       :::::     :::::     :::::           /
	.ASCII	/                   +/
	.ASCII	/+                       :::::     :::::     :::::           /
	.ASCII	/                   +/
	.ASCII	/+                       :::::     :::::     :::::           /
	.ASCII	/                   +/
	.ASCII	/+                   :::::::::::::::::::::::::::::::::       /
	.ASCII	/                   +/
	.ASCII	/+                   :::::::::::::::::::::::::::::::::       /
	.ASCII	/                   +/
	.ASCII	/+                   :::::::::::::::::::::::::::::::::       /
	.ASCII	/                   +/
	.ASCII	/+                    :::::                     :::::        /
	.ASCII	/                   +/
	.ASCII	/+                     :::::                   :::::         /
	.ASCII	/                   +/
	.ASCII	/+                       :::::               :::::           /
	.ASCII	/                   +/
	.ASCII	/+                         :::::           :::::             /
	.ASCII	/                   +/
	.ASCII	/+                   :::::    :::::     :::::    :::::       /
	.ASCII	/                   +/
	.ASCII	/+                   ::::::::::::::     ::::::::::::::       /
	.ASCII	/                   +/
	.ASCII	/+                   ::::::::::::::     ::::::::::::::       /
	.ASCII	/                   +/
	.ASCII	/+                   ::::::::::::::     ::::::::::::::       /
	.ASCII	/                   +/
	.ASCII	/+                                                           /
	.ASCII	/                   +/
	.ASCII	/+                                                           /
	.ASCII	/                   +/
	.ASCII	/++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++/
	.ASCII	/++++++++++++++++++++/

ASKL:	.ASCIZ	<CR><LF>/poworot wlewo  : /
ASKR:	.ASCIZ	<CR><LF>/poworot wprawo : /

.IF	DF	R$$T11
TSXS:	.ASCII	<ESC>/S/<ESC>/U/<200>
NOTIM:	.ASCIZ	<CR><LF>/net poddervki tajmera w sisteme/
.ENDC	;DF	R$$T11

	.END	START