	.TITLE	KEY
	.DSABL	GBL
	.GLOBL	TIME
	.GLOBL	KB$BUF	KB$SIZ

	.INCLU	"SCRMAC"

NEW$KB::
	MOV	R0,-(SP)
	MOV	R1,-(SP)
	MOVB	@#177562,R1
	CMPB	R1,#33
	BEQ	3$
	CMPB	R1,#212
	BNE	4$
3$:	INCB	BREAK

4$:	MOV	HEAD,R0
	CALL	NEXT
	CMP	R0,TILE
	BEQ	2$

	MOVB	R1,(R0)
	MOV	R0,HEAD
2$:	MOV	(SP)+,R1
	MOV	(SP)+,R0
	RTI

NEXT:	INC	R0
	CMP	R0,#KB$BUF+KB$SIZ
	BNE	1$
	MOV	#KB$BUF,R0
1$:	RETURN

KILKEY::
	MOV	HEAD,TILE
	CLR	REP
	CLRB	BREAK
	RETURN

WINPKEY::
1$:	CALL	TIME
	CMP	HEAD,TILE
	BEQ	1$
	CALL	.INPKEY
	RETURN

NEXTKEY::
	CMP	HEAD,TILE
	BEQ	1$
	.PUSH	R0
	MOV	TILE,R0
	CALL	NEXT
	MOVB	@R0,R1
	.POP	R0
	BIC	#^C377,R1
	RETURN
1$:	CLR	R1
	RETURN

INPKEY::
	CMP	(PC)+,(PC)+
HEAD:	.WORD	KB$BUF
TILE:	.WORD	KB$BUF
	BEQ	3$
.INPKEY	=	.
	MOV	TILE,R0
	CALL	NEXT
	MOV	R0,TILE

	MOV	R0,-(SP)
	CMP	R0,HEAD
	BEQ	4$
	CALL	NEXT
	CMPB	@(SP),(R0)
	BEQ	5$
REP	==	. + 2
4$:	CLR	#0
	BR	6$
5$:	INC	REP
6$:	MOV	(SP)+,R0

	MOVB	(R0),R0
	BIC	#^C377,R0
BREAK	==	. + 2
	CLRB	#0
	CMPB	R0,#224
	BEQ	1$

	CMPB	R0,#223
	BNE	2$

	INCB	ALT

;	TSTB	INVIEW
;	BNE	3$
ENALT	==	. + 2
	TSTB	#0
	BEQ	3$

	CALL	AHLINE
7$: 	CALL	WINPKEY
	CMPB	R0,#300
	BHIS	7$
	BR	HLINE

1$:
ALT	==	. + 2
	CLRB	#0
3$:	CLR	R0
	CALL	TIME
2$:	RETURN

AHLINE:
	MOV	R1,-(SP)
	MOV	#T$HLIN,R1
	BR	LINE
HLINE::
	MOV	R1,-(SP)
INVIEW	==	. + 2
	MOV	#0,R1
	MOV	.HLIN(R1),R1
LINE:	MOV	ATTR,-(SP)
	MOV	R2,-(SP)
	MOV	R3,-(SP)
	.WATTR	#^B1000
	MOV	#9.,R3
	MOV	#1,R2
1$:	.WPUT	R1,R2,#HEIGHT-1,#6
	ADD	#6,R1
	ADD	#8.,R2
	SOB	R3,1$
	INC	R2
	.WPUT	R1,R2,#HEIGHT-1,#6
	MOV	(SP)+,R3
	MOV	(SP)+,R2
	.WATTR
	MOV	(SP)+,R1
RET:	RETURN

HDIG::	MOV	#9.,R0
	MOV	#T.DIG,R1
	CLR	R2
1$:	.WPUT	R1,R2,#HEIGHT-1,#1
	INC	R1
	ADD	#7,R2
	.WCLR	R2,#HEIGHT-1,#1
	INC	R2
	SOB	R0,1$
	.WPUT	R1,R2,#HEIGHT-1,#2
	.WATTR	#^B0110
	RETURN

.HLIN:	.WORD	T.HLIN,	T.VHLI,	T.PHLI

T.HLIN:	.ASCII	"Help  Edit  View  RenMovCopy  "
	.ASCII	"UnprotProt  DeletePullDnQuit  "
T$HLIN:	.ASCII	"Left  Right             CmpDir"
	.ASCII	"      Pal   HistryEdit..EdtExt"
T.VHLI:	.ASCII	"Help  Hex   Rad50 Bytes Words "
	.ASCII	"Text  SearchViewerRusLatQuit  "
T.PHLI:	.ASCII	"Help  Mono  Color             "
	.ASCII	"                        Quit  "
T.DIG:	.ASCII	"12345678910"
	.EVEN
	.END
                                                                                                                                                                                                                                              