	.TITLE	OWNER
	.MCALL	.USBDF	.JSWDF
	.MCALL	.PRINT	.GTLIN	.EXIT
	.MCALL	.DBLK	.LOOKU	.CSTAT	.READW	
	.MCALL	.PURGE	.ENTER	.WRITW	.CLOSE
	.DSABL	GBL
	.GLOBL	..16

	.USBDF
	.JSWDF

.HILIM	=	50
.BEGIN	=	400
.BXOR	=	402
.EXOR	=	404
..HR	=	406
.BXOR2	=	410
.EXOR2	=	412
..HR2	=	414
.T.OWNER=	424

OWNER:	MOV	#T.OWN,R5
	.GTLIN	R5,#T.PRMT,WITHSPC

	.LOOKU	#AREA,#0,#DBLK
	BCC	3$
	JMP	E.LOOK

3$:	.CSTAT	#AREA,#0,#ADDR
	MOV	ADDR+4,R1
	SWAB	R1
	MOV	R1,WCNT

	.READW	#AREA,#0,#BUFF,R1,#0
	BCC	4$
	JMP	E.READ

4$:	MOV	BUFF+.T.OWNER,R1
	ADD	#BUFF,R1
	CLR	BUFF+.T.OWNER

	MOV	#50.,R0
7$:	MOVB	(R5)+,(R1)+
	BEQ	8$
	SOB	R0,7$
	.PRINT	#T.TRK

8$:	CLRB	@R1
	MOV	#4,R3
	MOV	BUFF+.BXOR,R0
	MOV	BUFF+.BXOR2,R1
	CALL	STORE
	MOV	BUFF+.EXOR,R0
	MOV	BUFF+.EXOR2,R1
	CALL	STORE
	MOV	BUFF+..HR,R0
	MOV	BUFF+..HR2,R1
	CALL	STORE

	MOV	#40,R0
	MOV	#136574,R1
	MOV	BUFF+..HR,R5
	ADD	#BUFF+2,R5
5$:	XOR	R1,(R5)+
	SOB	R0,5$

	MOV	#23432,R1
	MOV	#136436,R2
	MOV	BUFF+.BEGIN,R4
	MOV	BUFF+.HILIM,R5
	ADD	#BUFF,R4
	ADD	#BUFF,R5
	MOV	R5,R0
	SUB	R4,R0
	ASR	R0
1$:	XOR	R1,(R4)+
	XOR	R2,-(R5)
	ADD	#124434,R1
	ADD	#65354,R2
	SOB	R0,1$

	MOV	#34526,R1
	MOV	#53433,R2
	MOV	BUFF+.BXOR,R4
	MOV	BUFF+.EXOR,R5
	ADD	#BUFF,R4
	ADD	#BUFF,R5
	MOV	R5,R0
	SUB	R4,R0
	ASR	R0
2$:	XOR	R1,(R4)+
	XOR	R2,-(R5)
	ADD	#127654,R1
	ADD	#121432,R2
	SOB	R0,2$

	CLR	BUFF+.BEGIN
	CLR	BUFF+.BXOR
	CLR	BUFF+.EXOR
	CLR	BUFF+..HR
	CLR	BUFF+.BXOR2
	CLR	BUFF+.EXOR2
	CLR	BUFF+..HR2
	CLR	BUFF+.T.OWNER

	BIS	#OVLY$,BUFF+JSW

	.PURGE	#0
	.ENTER	#AREA,#0,#.DBLK,ADDR+4
	BCS	E.ENT

	.WRITW	#AREA,#0,#BUFF,WCNT,#0
	BCS	E.WRIT

	.CLOSE	#0
	BCS	E.CLO

	MOV	#T.OK,R0
	.PRINT
	.EXIT

E.LOOK:	MOV	#T.LOOK,R0
	BR	E.
E.READ:	MOV	#T.READ,R0
	BR	E.
E.ENT:	MOV	#T.ENT,R0
	BR	E.
E.WRIT:	MOV	#T.WRIT,R0
	BR	E.
E.CLO:	MOV	#T.CLO,R0
E.:	.PRINT
	BISB	#ERROR$,@#USERRB
	.EXIT

STORE:	ASR	R0
	SWAB	R0
	ADD	#BUFF,R1
	JMP	..16

WCNT:	.WORD
AREA:	.BLKW	5
ADDR:	.BLKW	6
DBLK:	.DBLK	DK,PC,2
.DBLK:	.DBLK	DK,PC,EXE

T.OK:	.ASCIZ	"OK"
T.LOOK:	.ASCIZ	"LOOKUP"
T.READ:	.ASCIZ	"READW"
T.ENT:	.ASCIZ	"ENTER"
T.WRIT:	.ASCIZ	"WRITW"
T.CLO:	.ASCIZ	"CLOSE"
T.PRMT:	.ASCII	"Owner: "<200>
T.TRK:	.ASCIZ	"Owner ID truncated at 50 characters"
T.OWN:	.BLKB	81.
	.EVEN

BUFF:	.END	OWNER
                                                                                                                                                                                                                                     