	.TITLE	SAVINI
	.MCALL	.PURGE	.CLOSE
	.MCALL	.FPROT	.ENTER	.WRITW
	.DSABL	GBL
	.GLOBL	CNVDEV	RAD
	.GLOBL	AREA	BUFF
	.GLOBL	ENTRY
	.GLOBL	$PANEL	$0	$1
	.GLOBL	CTRLO
	.GLOBL	AUTORR	CLOCK	X.PAL	TB.PAL
	.GLOBL	DEV	MODE	TSORT
	.GLOBL	L.EDIT

	.INCLU	"SCRMAC"
	.INCLU	"DIAMAC"

LE.EDIT	=	30.

.MACRO	.IFERR	LABEL
	JSR	R5,IFERR
	.WORD	LABEL
.ENDM

S.F9::	.DIALOG	#D.SVS
	DEC	R1
	BEQ	CONT
.ENTRY:	JMP	ENTRY

CONT:	MOV	#^RSY ,R0
	CALL	CNVDEV
	MOV	#T.PE,R1
	CALL	RAD
	.DIALOG	#D.SAVING

1$:	.PURGE	#0
	.FPROT	#AREA,#0,#INI,#0
	.ENTER	#AREA,#0,#INI,#1
	.IFERR	1$

	MOV	#400,R0
	MOV	#BUFF,R1
2$:	MOV	#^RPAF,(R1)+
	SOB	R0,2$

	MOV	#TOSAVE,R4
	MOV	#$PANEL,@R4
	ADD	-(R5),R5
	MOV	DEV(R5),2(R4)

	MOV	#BUFF+2,R3
3$:	MOV	(R4)+,R0
	BEQ	4$
	MOV	@R0,(R3)+
	BR	3$

4$:	MOV	#400-1,R0
	MOV	#BUFF+2,R1
	CLR	R2
5$:	ADD	(R1)+,R2
	ADC	R2
	SOB	R0,5$
	MOV	R2,BUFF

6$:	.WRITW	#AREA,#0,#BUFF,#400,#0
	.IFERR	6$

7$:	.CLOSE	#0
	.IFERR	7$

CANCEL:	CLRB	ING
	.WRES
	.WSCUR
	BR	.ENTRY

IFERR:	BCC	1$
	TST	(SP)+
	.DIALOG	#D.ESAVING
	.WHCUR
	DEC	R1
	BNE	CANCEL
	JMP	@(R5)+

1$:	TST	(R5)+
	RTS	R5

INI::	.RAD50	"SY PC    INI"

TOSAVE::
	.WORD	0		,0
	.WORD	$0+MODE		,$1+MODE
	.WORD	$0+TSORT	,$1+TSORT
	.WORD	CTRLO
	.WORD	AUTORR		,CLOCK
	.WORD	X.PAL
	.WORD	TB.PAL		,TB.PAL+2

..	=	0
.REPT	LE.EDIT/2
	.WORD	..	+	L.EDIT
		..	=	.. + 2
.ENDR
	.WORD

	.END
                                                                                                                       